kittybox:
{ lib, ... }: {
  name = "nixos-kittybox";

  nodes = {
    kittybox = { config, pkgs, lib, ... }: {
      imports = [ kittybox.nixosModules.default ];

      services.postgresql = {
        enable = true;
        ensureDatabases = ["kittybox"];
        ensureUsers = [ {
          name = "kittybox";
          ensurePermissions = {
            "DATABASE kittybox" = "ALL PRIVILEGES";
          };
        } ];
      };

      services.kittybox = {
        enable = true;
        logLevel = "info,kittybox=debug,retainer::cache=warn,h2=warn,rustls=warn";
        backendUri = "postgres://localhost?host=/run/postgresql&dbname=kittybox";
      };

      systemd.services.kittybox.wants = [ "postgresql.service" ];
      systemd.services.kittybox.after = [ "postgresql.service" ];

      environment.systemPackages = with pkgs; [
        xh
      ];
    };
  };

  # TODO: Make e2e tests for authentication endpoints and such
  # Potentially using WebDriver
  # Could also be implemented with fantoccini
  testScript = ''
    with subtest("Verify that Kittybox started correctly..."):
        kittybox.wait_for_open_port(8080)
        kittybox.succeed("xh --no-check-status http://localhost:8080/.kittybox/micropub")

    with subtest("Onboarding should correctly work..."):
        kittybox.copy_from_host("${./onboarding.json}", "/root/onboarding.json")
        kittybox.succeed("xh --follow http://localhost:8080/.kittybox/onboarding -j @/root/onboarding.json")
        # Testing for a known string is the easiest way to determine that the onboarding worked
        kittybox.succeed("xh http://localhost:8080/ | grep 'vestige of the past long gone'")
'';
}